// -*- ASCII:EDT -*-
//  getVariables.edt
// prompts all local variables
//  and offers to release them
// (schlicht 20010104)
//////////////////////////////

IfStr("%!0","","=",>
   "Release('Variables');",>
  !"Assign('Variables',' %%!0   =   |%!0|%\');");
Assign("temp0","%!0");

LetRegNum(0,1);
Loop(!`>
   Do(">
      IfStr('%%!%!0','','=','',>
         !'Assign(''Variables'',''%%$(|Variables|); %%%%!%!0   =   |%%!%!0|%\'');>
      ');>
   ");>
   IfNum(%!0,9,'=','Stop','LetRegNum(0,%!0+1);');>
`);

IfStr("%!?","","=","",!"Assign('Variables','%$(''Variables''); %%!?   =   |%!?|%\');");
IfStr( "%?","","=","",!"Assign('Variables','%$(''Variables''); %%?    =   |%?|%\');");

LetReg(0,"%$('temp0');");

IfStr("%$('Variables');","","=",>
   "Prompt('All variables free.',0,1)",>
  !"Prompt('%$(|Variables|);%\      Keep ?',1,3,'',>
     !'LetRegNum(0,0);>
       Loop(!''>
          IfNum(%!0,9,|=|,|Stop|,|LetRegNum(0,%!0+1);|);>
          LetReg(%!0,||);>
       '');>
       LetReg(0,'''');>
      ');>
   ");

End;


/////////////////////////////////////
// This macro prompts all used variables
// and offers to release them.
// (Note: %? and %!? cannot be released.)
//
// R Schlicht   w.m.l@gmx.net
/////////////////////////////////////
$Id: getVariables.edt,v 1.2 2001-11-13 19:01:30+01 standard Exp standard $