// -*- ASCII:EDT -*-
// Gets all opened files,
// checks which file need compiling,
// and compiles these.
// (schlicht 20010616)
/////////////////////////////////

ChDir("%p");
SaveAll(0,0,0,1,0);
ListOpenedFiles(0,0,"JAVA",".java",1,0);
LetRegNum(2,0);
Loop(!`>
   SetOK(1);>
   FindInString("%!0","<*>",1,2,1001,%!2);>
   IfOK(!"FindInString('%!0','.java',3,4,1000,%!1);>
      ExtractByIndex(9,'%!0',%!1,%!3-1);>
      IfFileExists('%!9.class',>
         !'IfFileOlder(''%!9.java'',''%!9.class'','''',>
            !''// The java file has been edited:<>
               Open(|%!9.java|); >
               StartWorking(|javac %n [changed]|);>
               WinExe(||,|javac.exe -g %n.java|,|%P|,|javac %n [changed]|,011111,1,||,||,|%n.log|);>
               StopWorking;>
               ErrorLogUpdate;>
               IfLogErrors(|>
                  ShowErrorLog(1); CMD(||Errors...||); Exit;|,>
                 |ShowErrorLog(0);|);'');',>
         !'// The class file does not exist, let's compile:<>
           Open(''%!9.java''); >
           StartWorking(''javac %n [new]'');>
           WinExe('''',''javac.exe -g %n.java'',''%P'',''javac %n [new]'',011111,1,'''','''',''%n.log'');>
           StopWorking;>
           ErrorLogUpdate;>
           IfLogErrors(''>
                ShowErrorLog(1); CMD(|Errors...|); Exit;'',>
              ''ShowErrorLog(0);'');');>
      LetRegNum(2,%!2+1);",>
   "Stop;");>
`);
End;

/////////////////////////////////////////
// This macro presumes that
// all files that belong to the project
// are currently opened.
//
// If the java bin directory is not
// in your Windows' PATH I would
// suggest to put it in your
// autoexec.bat file.
// Otherwise you would have to
// specify the full path.
//
// R Schlicht   w.m.l@gmx.net
//////////////////////////////////////////
$Id: compilePrj53.edt,v 1.3 2001-11-13 19:01:57+01 standard Exp standard $